Public Function GetExtension01(sFile As String) As String
' by Donald, donald@xbeat.net, 20001010
' the fastest you can get using Asc and Mid$, but still bad
  Dim iPos As Long
  
  For iPos = LenB(sFile) To 1 Step -2
    Select Case AscW(MidB$(sFile, iPos - 1))
    Case 46
      GetExtension01 = Mid$(sFile, iPos \ 2 + 1)
      Exit Function
    Case 92
      ' dir extensions don't count
      Exit Function
    End Select
  Next
  
End Function

Public Function GetExtension02(sFile As String) As String
' by Donald, donald@xbeat.net, 20001010
  Dim iPos As Long
  Dim iPosPrev As Long
  
  ' search last dot
  Do
    iPosPrev = iPos
    iPos = InStr(iPos + 1, sFile, ".", vbBinaryCompare)
  Loop While iPos > 0
  
  If iPosPrev > 0 Then
    ' must be right of last backslash
    If InStr(iPosPrev + 1, sFile, "\", vbBinaryCompare) = 0 Then
      GetExtension02 = Mid$(sFile, iPosPrev + 1)
    End If
  End If
  
End Function

Public Function GetExtension03(sFile As String) As String
' by Peter Weighill, pweighill@btinternet.com, 20001020
' Only for VB6
  Dim iPos As Long
  Dim iPos2 As Long
  
  ' search last dot
  iPos = InStrRev(sFile, ".", -1, vbBinaryCompare)
  iPos2 = InStrRev(sFile, "\", -1, vbBinaryCompare)
  
  If iPos > iPos2 Then
      GetExtension03 = Mid$(sFile, iPos + 1)
  End If
End Function

Public Function GetExtension04(sFile As String) As String
' by Peter Weighill, pweighill@btinternet.com, 20001021
' Only for VB6
  Dim iPos As Long

  ' search last dot
  iPos = InStrRev(sFile, ".", -1, vbBinaryCompare)

  If iPos > 0 Then
    If InStr(iPos + 1, sFile, "\", vbBinaryCompare) = 0 Then
      GetExtension04 = Mid$(sFile, iPos + 1)
    End If
  End If
End Function

Public Function GetExtension05(sFile As String) As String
' by Peter Weighill, pweighill@btinternet.com, 20001022
' Requires Reference to Microsoft Scripting Runtime
    Static fso As Scripting.FileSystemObject

    If fso Is Nothing Then
        Set fso = New Scripting.FileSystemObject
    End If
    GetExtension05 = fso.GetExtensionName(sFile)
End Function