Public Function MakeWord01(LoByte As Byte, HiByte As Byte) As Integer
  If HiByte And &H80 Then
    MakeWord01 = ((HiByte * &H100&) + LoByte) Or &HFFFF0000
  Else
    MakeWord01 = (HiByte * &H100) + LoByte
  End If
End Function
  

Public Function MakeWord02(LoByte As Byte, HiByte As Byte) As Integer
  If HiByte And &H80 Then
    MakeWord02 = ((HiByte * &H100&) Or LoByte) Or &HFFFF0000
  Else
    MakeWord02 = (HiByte * &H100) Or LoByte
  End If
End Function
  

Public Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" _
    (pDst As Any, pSrc As Any, ByVal ByteLen As Long)


Public Function MakeWord03(LoByte As Byte, HiByte As Byte) As Integer
  CopyMemory MakeWord03, LoByte, 1&
  CopyMemory ByVal VarPtr(MakeWord03) + 1&, HiByte, 1&
End Function
  

Private Type T1Int
  iWord As Integer
End Type
Private Type T2Byte
  bLoByte As Byte
  bHiByte As Byte
End Type


Public Function MakeWord04(LoByte As Byte, HiByte As Byte) As Integer
  Dim u2Byte As T2Byte
  Dim u1Int As T1Int
  u2Byte.bLoByte = LoByte
  u2Byte.bHiByte = HiByte
  LSet u1Int = u2Byte
  MakeWord04 = u1Int.iWord
End Function