Public Function InStrRev01( _
                            sCheck As String, _
                            sMatch As String, _
             Optional ByVal Start As Long = -1, _
                   Optional Compare As VbCompareMethod = vbBinaryCompare) As Long
' by Donald, donald@xbeat.net, rev. 001, 20000923
' strategy: search left to right until no more
  Dim lenSearchFor As Long
  Dim posFound As Long
  
  lenSearchFor = Len(sMatch)
  
  If lenSearchFor Then
    If Start <= 0 Then
      Start = Len(sCheck)
    End If
    Do
      posFound = InStr(InStrRev01 + 1, sCheck, sMatch, Compare)
      If posFound And (posFound + lenSearchFor - 1 <= Start) Then
        ' match
        InStrRev01 = posFound
      Else
        ' no more
        Exit Function
      End If
      ' condition not necessary
    Loop
  Else
    ' as VB6 InStrRev
    If Start <= Len(sCheck) Then
      InStrRev01 = Start
    End If
  End If

End Function

Public Function InStrRev02( _
                            sCheck As String, _
                            sMatch As String, _
             Optional ByVal Start As Long = -1, _
                   Optional Compare As VbCompareMethod = vbBinaryCompare) As Long
' by Donald, donald@xbeat.net, 20000923
' strategy: search right to left until found
  Dim lenSearchFor As Long
  Dim posFound As Long
  Dim posSearch As Long
 
  lenSearchFor = Len(sMatch)
  
  If lenSearchFor Then
    If Start <= 0 Then
      Start = Len(sCheck)
    End If
    For posSearch = Start - lenSearchFor + 1 To 1 Step -1
      posFound = InStr(posSearch, sCheck, sMatch, Compare)
      If posFound Then
        If (posFound + lenSearchFor - 1) <= Start Then
          InStrRev02 = posFound
          Exit Function
        End If
      End If
    Next
  Else
    ' as VB6 InStrRev
    If Start <= Len(sCheck) Then
      InStrRev02 = Start
    End If
  End If
  
End Function

Public Static Function InStrRev03( _
    ByRef sCheck As String, _
    ByRef sMatch As String, _
    Optional ByVal Start As Long, _
    Optional ByVal Compare As VbCompareMethod = vbBinaryCompare, _
    Optional ByVal Stopp As Long = 1 _
  ) As Long
' by Jost Schwider, jost@schwider.de, 20001124
  
  Dim Index As Long
  Dim Pivot As Long
  
  If Len(sMatch) Then
  
    'Linke Grenze bestimmen:
    Stopp = InStr(Stopp, sCheck, sMatch, Compare)
    If Stopp = 0 Then Exit Function
    
    'Rechte Grenze bestimmen:
    If Start <= 0 Then
      Start = Len(sCheck) - Len(sMatch) + 1
    Else
      Start = Start - Len(sMatch) + 1
    End If
    If Stopp > Start Then Exit Function
    
    'Ersten Treffer merken:
    InStrRev03 = Stopp
    Stopp = Stopp + 1
    
    'Binäre Suche / Intervall-Halbierungs-Verfahren:
    Do
      'Ab Mitte testen:
      Pivot = (Stopp + Start) \ 2
      Index = InStr(Pivot, sCheck, sMatch, Compare)
      
      'Treffer?
      If Index Then
        If Index > Start Then
          'ungültiger Treffer:
          Start = Pivot - 1
        Else
          InStrRev03 = Index
          Stopp = Index + 1
        End If
      Else
        Start = Pivot - 1
      End If
    Loop Until Stopp > Start
  
  Else
    If Start <= Len(sCheck) Then InStrRev03 = Start
  End If

End Function

Private Declare Sub PokeLng Lib "kernel32" Alias "RtlMoveMemory" ( _
    ByVal Addr As Long, Value As Long, _
    Optional ByVal Bytes As Long = 4)

Public Function InStrRev06( _
    ByRef sCheck As String, _
    ByRef sMatch As String, _
    Optional ByVal Start As Long, _
    Optional ByVal Compare As VbCompareMethod = vbBinaryCompare _
  ) As Long
' by Jost Schwider, jost@schwider.de, 20001218
  Dim Stopp As Long
  Dim Index As Long
  Dim Pivot As Long
  Dim Length As Long
  Dim LengthPtr As Long
  Dim MatchLen As Long
  
  If Compare = vbBinaryCompare Then
    MatchLen = LenB(sMatch) - 1
    If MatchLen > -1 Then
    
      'Linke Grenze bestimmen:
      Stopp = InStrB(sCheck, sMatch)
      If Stopp = 0 Then Exit Function
      
      'Rechte Grenze bestimmen:
      Length = LenB(sCheck)
      If Start <= 0 Then
        Start = Length - MatchLen
        LengthPtr = StrPtr(sCheck) - 4
      Else
        Start = Start + Start - MatchLen
        If Stopp > Start Then Exit Function
        LengthPtr = StrPtr(sCheck) - 4
        PokeLng LengthPtr, Start + MatchLen
      End If
      
      'Ersten Treffer merken:
      InStrRev06 = Stopp
      Stopp = Stopp + 2
      
      'Binäre Suche / Intervall-Halbierungs-Verfahren:
      Do
        'Ab Mitte testen:
        Pivot = (Stopp + Start) \ 2
        Index = InStrB(Pivot, sCheck, sMatch)
        
        'Treffer?
        If Index Then
          InStrRev06 = Index
          If Index >= Start Then
            PokeLng LengthPtr, Length
            InStrRev06 = InStrRev06 \ 2 + 1
            Exit Function
          End If
          Stopp = Index + 2
        Else
          If Stopp + 8 >= Pivot Then Exit Do
          Start = Pivot - 1
          PokeLng LengthPtr, Start + MatchLen
        End If
      Loop
      
      'Konventionell weiter machen:
      Index = InStrB(Stopp, sCheck, sMatch)
      Do While Index
        InStrRev06 = Index
        Index = InStrB(Index + 2, sCheck, sMatch)
      Loop
      InStrRev06 = InStrRev06 \ 2 + 1
      PokeLng LengthPtr, Length
    
    Else
      If Start <= Len(sCheck) Then InStrRev06 = Start
    End If
  Else
    InStrRev06 = InStrRev06(LCase$(sCheck), LCase$(sMatch), Start)
  End If
End Function